ReadFile - Learn To Code - PlayBASIC Documentation

ReadFile

ReadFile Filename$, ChannelIndex

Parameters:

Filename$ = The name of the file you wish to read data from
ChannelIndex = Indes of the file channel to use

Returns: NONE

      ReadFile opens a file for read access. The command requires both the filename to open for reading, and a file channel index for use with subsequent reading commands (ie ReadByte, ReadWord, ReadInt etc etc.

      Files can be accessed both sequentially and randomly. However, files can NOT be written to when opened with ReadFile

Sequential Access

      Sequential file access, is when you step through the file in order, in other words, you begin reading at the start of the file, and continue reading through it from start to finish. Never stepping backward or skipping forward.

Random Access

      Random file access, is where you jump around through the file reading one section, then perhaps jumping back or skipping forward. So your randomly accessing parts of file at will. This is often invaluable when you need to read data sections found in image files, or constructing your own pack file format.

FACTS:

* Files Opened with READFILE can not be written to.

Mini Tutorial:

This example creates a simple file with some various bits of data store in it, then read it's back again.

  File$=TempDir$()+"PB_TestFile.txt"

; CReate a File for writing data to
  WriteFile File$,1

; Write a Byte to file channel 1, of value 200
  WriteByte 1,200

; Write a Word to file channel 1, of value 64000
  WriteWord 1,64000

; Write a INTEGER to file channel 1, of value 123456
  WriteInt 1,123456

; Write a FLOAT to file channel 1, of value 123.456
  WriteFloat 1,123.456

; Write a String to file channel 1, of value Hello World
  WriteString 1,"Hello World"

; Close this file channel
  CloseFile 1


  Print "============================"
  Print "Reading File:"+File$
  Print "============================"


; Open a file to READ with READFILE
  ReadFile File$,1

; Read and display the byte value
  Print "   Byte Data:"+Str$(ReadByte(1))

; Read and display the word value
  Print "   Word Data:"+Str$(ReadWord(1))

; Read and display the Integer value
  Print "Integer Data:"+Str$(ReadInt(1))

; Read and display the Float value
  Print "  Float Data:"+Str$(ReadFloat(1))

; Read and display the String value
  Print "  String Data:"+ReadString$(1)

; Close this file channel
  CloseFile 1


  If FileExist(file$) Then DeleteFile file$

; Display the screen and wait for a key press
  Sync
  WaitKey

This example would output.

  ============================
  Reading File:C:Windows\temp\Pb_TestFile.txt
  ============================
  Byte Data:200
  Word Data:64000
  Integer Data:123456
  Float Data:123.456
  String Data:Hello World


Related Info:	CloseFile \| ReadByte \| ReadByteAt \| ReadChr$ \| ReadChrAt$ \| ReadFloat \| ReadFloatAt \| ReadInt \| ReadIntAt \| ReadString$ \| ReadStringAt$ \| ReadValue \| ReadValue# \| ReadWord \| ReadWordAt :