PointHitSpritePixels - Learn To Code - PlayBASIC Documentation

PointHitSpritePixels

CollisionState = PointHitSpritePixels(PointX, PointY, SpriteIndex, Accuracy#)

Parameters:

    PointX = The points X coordinate
    PointY = The points Y coordinate
    SpriteIndex = The Sprite to check for collision against
    Accuracy# = The level of accuracy that should be used.

Returns:

CollisionState = The result of the collision query (0= No collision ,1 = Collision)

     The PointHitSpritePixels function detects if a collision occurs between a point and a pixel of sprite.

Example Accuracy Values
      0.25 = Reduce collision accuracy to 25%
      0.50 = Reduce collision accuracy to 50%
      0.75 = Reduce collision accuracy to 75%
      1.00 = Set collision accuracy to 100%
      2.00 = Set collision accuracy to 200%

FACTS:

      * The Accuracy parameter allows the user to fine tune the quality of the pixel level sprite collisions. Generally speaking the lower the quality the faster the comparison. On the flip side the higher the quality the more accurate but slower the comparison. It's up to the user to choose a accuracy level that is appropriate for your sprite images and the performance of your game.

      * Pixels level collisions ignore the sprites transparent colour.

      * Also see SpriteCollisionMode

Mini Tutorial:

This example creates a random image, creates 10 randomly positioned sprites on the screen using this image. The main loop rotates the sprites while scans them for collisions using PointHitSpritePixels

; clear the screen to black
  Cls RGB(0,0,0)

; Make an image with circles on it
  For lp =0 To 100
     CircleC Rnd(100),Rnd(100),RndRange(2,10),1,RndRGB()
  Next
  GetImage 1,0,0,100,100
  PrepareFXImage 1


; Make 10 sprites
  For spr=1 To 10

   ; psition the spriotye randomly on the screen
     x=Rnd(GetScreenWidth())
     y=Rnd(GetScreenHeight())

   ; Create the sprite
     Spr=NewSprite(x,y,1)

     CenterSpriteHandle spr
     SpriteCollision spr,on

   ; Set sprite collision to Rotated rectangles
     SpriteCollisionMode Spr,1
  Next



  Do
     Cls RGB(0,0,0)

   ; Check if the mouse  is over a sprite
     mx#=MouseX()
     my#=MouseY()


   ; start for/next loop from 1 to 10
     For spr=1 To 10

      ; Turn this sprite
        TurnSprite spr,0.25

      ; Check if a point(the mouse) is over this sprite
        If PointHitSpritePixels(mx#,my#,Spr,1)=true
         ; if the mouse pointer over sprite
         ; then make it flash
           SpriteDrawMode Spr,2+4096
        Else
         ; Set it's draw mode to just rotated
           SpriteDrawMode Spr,2
        EndIf

     Next


     DrawAllSprites

   ; draw the test point
     DotC mx#,my#,RGB(255,255,255)


     Sync
  Loop


Related Info:	CircleHitSprite \| PointHitSprite \| QuadHitSprite \| RayHitSprite \| RectHitSprite \| ShapeHitSprite \| SpriteCollisionMode \| SpriteHit \| SpritesOverlap :