Wave Image Demo (Horizontal, Vertical, Combined & Double Ripple Effects)


This example perform the classic sinus wave distortion along the X / Y and combined axis's.

  * CopyStripV (vertical ripple)
  * CopyStripH (horizontal ripple)



PlayBASIC Code:
    
    setfps 100

    LoadFont "courier new",1,32,8
    fontdrawmode 1,1  ;  
    
    ThisIMAGE = LoadNewFXImage("FILE-NAME-OF_IMAGE-TO_LOAD")
    
    Width    = GetImageWidth(ThisIMAGE)
    Height    =    GetImageHeight(ThisIMAGE)
    
    TempImage = NewfxImage(Width,Height)    
    TempImage2 = NewfxImage(Width,Height)    
    
    
    Do

        cls        
        
        select Method

            ; --------------------------------------------------------
            case 0            
            ; --------------------------------------------------------
                HoriWave(ThisIMAGE,0,Angle#    ,0.1    ,100)

            ; --------------------------------------------------------
            case 1
            ; --------------------------------------------------------
                VertWave(ThisIMAGE,0,Angle#    ,0.11    ,100)
    
            ; --------------------------------------------------------
            case 2
            ; --------------------------------------------------------
                HoriWave(ThisIMAGE,TempIMAGE    ,Angle#        ,0.2        ,200)
                VertWave(TempIMAGE,0                ,Angle#        ,0.11        ,200)
                CLsIMAGE(TempIMAGE,0)
                

            ; --------------------------------------------------------
            case 3
            ; --------------------------------------------------------

                HoriWave(ThisIMAGE,TempIMAGE    ,Angle#        ,1        ,10)
                VertWave(TempIMAGE,TempIMAGE2    ,Angle2#    ,1        ,10)
                CLsIMAGE(TempIMAGE,0)

                HoriWave(TempIMAGE2,TempIMAGE    ,Angle2#        ,0.2    , 100+sin(angle2#)*50)
                VertWave(TempIMAGE,0                ,Angle2#        ,0.11    , 50)
                CLsIMAGE(TempIMAGE2,0)

        endselect
    
    
        if ScanCode()
            if enterkey()
                Method=wrapvalue(Method+1,0,4)
                flushkeys
            endif
        endif            
    
        print Fps()

        Angle#    =wrapangle(Angle#,1.1)
        Angle2#    =wrapangle(Angle2#,0.35)
        
        Sync        
    loop spacekey()






Function CLsIMAGE(ThisIMAGE,ThisCOLOUR)
            rendertoimage ThisIMAGE
            Cls ThisCOLOUR
            rendertoscreen
ENdFunction 




Function HoriWave(SrcIMAGE,DestIMAGE,Angle#,AngleStep#,Radius#)

            Width    =GetImageWidth(SrcIMage)
            Height=GetImageHeight(SrcIMage)
    
            lockbuffer
                for ylp=0 to Height-1
                    x =sin(Angle#+(ylp*AngleStep#))*Radius#
                    CopyStripH SrcIMAGE,ylp,0,Width , DestIMAGE, X , ylp  
                next
            unlockbuffer
    
EndFunction 


Function VertWave(SrcIMAGE,DestIMAGE,Angle#,AngleStep#,Radius#)

            Width    =GetImageWidth(SrcIMage)
            Height=GetImageHeight(SrcIMage)
            lockbuffer
                for Xlp=0 to Width-1
                    y =sin(Angle#+(Xlp*angleStep#))*Radius#
                    CopyStripV SrcIMAGE,Xlp,0,Height , DestIMAGE, xlp,y
                next
            unlockbuffer
EndFunction